Script: Cambio opzioni risparmio energetico

Cambio opzioni risparmio energetico tramite script per aumentare le prestazione del pc

Risparmio energetico spegne i core della cpu Ultimamente abbiamo avuto qualche problemino con notebook di fascia business con processore Intel Mobile series, nel nostro caso i7-5500U, che risultavano molto lenti; appena ho visto negli eventi che il processore veniva spento per il risparmio energetico ho capito che si poteva risolvere anche con uno script.

Il mio script disattiva l’ibernazione, attiva le ‘ Prestazioni Massime ‘ , non permette lo spegnimento del hard disk (alimentato o a batteria) e cancella le opzioni ‘ Bilanciato ‘ e ‘ Risparmio di energia ‘ dal pannello di controllo – ‘ Opzioni risparmio energia ‘ in modo che l’utente non vada a ricambiare le opzioni e ci ritroviamo con il problema

rem Aumento prestazioni da opzioni risparmio energia
rem Andrea Cavazzi da www.itmaniac.it
rem ver 1.1.0

@Echo Off
Title Prestazioni Elevate v1.1.0 & Color 1A
cd %systemroot%\system32
call :IsAdmin

rem disattivo l'ibernazione del pc
Echo *-------------------------------
POWERCFG hibernate off
Echo Disattivato ibernazione

rem attivo opzione Prestazioni Massime 
Echo *-------------------------------
POWERCFG -setactive 8c5e7fda-e8bf-4a96-9a85-a6e23a8c635c
Echo Attivo opzione Prestazioni Massime

rem rendo hd sempre attivo, quindi non lo spegne mai
Echo *-------------------------------
POWERCFG -x -disk-timeout-ac 0
POWERCFG -x -disk-timeout-dc 0
Echo Abilitato HD sempre attivo

rem cancello opzione Bilanciato
Echo *-------------------------------
Echo Cancello opzione Bilanciato
POWERCFG -d a1841308-3541-4fab-bc81-f71556f20b4a

rem cancello opzione Risparmio di energia
Echo *-------------------------------
Echo Cancello opzione Risparmio di energia
POWERCFG -d 381b4222-f694-41f0-9685-ff5bb260df2e

Echo *-------------------------------
Echo * Applicate modifiche per aumentare al massimo le prestazioni
Echo *-------------------------------
Pause & Exit

:IsAdmin
Reg.exe query "HKU\S-1-5-19\Environment"
If Not %ERRORLEVEL% EQU 0 (
 Cls & Echo Devi avere i diritti amministrattivi per eseguire questo script ... 
 Pause & Exit
)
Cls
goto:eof

Lo script è un file batch, quindi basta incollarlo in notepad e salvarlo con estensione .bat ed eseguirlo con privilegi amministrativi, oppure potete scaricare lo script.

Download  VirusTotal: OK

Funziona su tutte le versioni di Windows 7 / 8 / 10 sia a 32 bit che a 64

Aggiornamento 15/10/16: inserito nello script il controllo per UAC

Potrebbero interessarti anche...

Lascia un commento

Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *

Questo sito usa Akismet per ridurre lo spam. Scopri come i tuoi dati vengono elaborati.